Compilare Java da Mac con TextWrangler

Passando da windows a mac mi sono trovato nella situazione di trovare un programma equivalente a programmer notepad per il sistema operativo della mela. Cercando qua e la in giro per internet ho letto che uno tra i migliori è TextWrangler (scaricabile da qua: http://www.barebones.com/products/textwrangler/)
L'unico grande difetto di questo programma è l'impossibilità di compilare il codice scritto. Fortunatamente esiste una soluzione a questo problema, basta aggiungere due script e il gioco è fatto.

• Aprire TextWrangler 
• dalla barra di menù selezionare la penultima icona (quella prima di help) e selezionare open script editor
• copiare il seguente codice:

tell application "TextWrangler"
    save text document 1
    set the_file to file of text document 1
end tell

set AppleScript's text item delimiters to ":"
set source_file to the last text item of (the_file as string)

tell application "Finder"
    set the_folder to container of (the_file as alias) as alias
end tell

tell application "Terminal"
    activate
    set shell_script to "cd " & (quoted form of POSIX path of the_folder) & ¬
        "; javac " & source_file
    if (count windows) is 0 then
        do script shell_script
    else
        do script shell_script in the front window
    end if
end tell

• chiudere e salvare il file con il nome "Compile Java" nella cartella: Machintosh HD/Utenti/nome_utente/Library/Application Support/TextWrangler/Script 
• Riaprire lo scripte editor e copiare il seguente codice

tell application "TextWrangler"
    set the_file to file of text document 1
end tell

set AppleScript's text item delimiters to ":"
set source_file to the last text item of (the_file as string)
set compiled_file to text 1 thru -6 of source_file

tell application "Finder"
    set the_folder to container of (the_file as alias) as alias
end tell

tell application "Terminal"
    activate
    set shell_script to "cd " & (quoted form of POSIX path of the_folder) & ¬
        "; java " & compiled_file
    if (count windows) is 0 then
        do script shell_script
    else
        do script shell_script in the front window
    end if
end tell

• chiudere e salvare il file con il nome "Run Java" nella cartella: Machintosh HD/Utenti/nome_utente/Library/Application Support/TextWrangler/Script  
• Chiudete e riaprite TextWrangler e nel penultimo menu troverete le voci Compile Java e Run Java con le quali potrete così compilare ed eseguire le vostre applicazioni java.